src/app/app.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

include(../../qmmp.pri)

TEMPLATE = app

unix:TARGET = ../../bin/qmmp
win32:TARGET = ../../../bin/qmmp

QT += network

HEADERS += qmmpstarter.h \
           builtincommandlineoption.h

SOURCES += qmmpstarter.cpp \
           builtincommandlineoption.cpp \
           main.cpp

RESOURCES = images/images.qrc translations/qmmp_locales.qrc

INCLUDEPATH += ../


unix {
    LIBS += -lqmmp -lqmmpui
    QMAKE_LIBDIR += ../../lib
    target.path = $$BIN_DIR
    desktop.files = qmmp.desktop \
        qmmp-enqueue.desktop \
        qmmp-dir.desktop
    desktop.path = $$DATA_DIR/applications
    icon16.files = images/16x16/qmmp.png
    icon32.files = images/32x32/qmmp.png
    icon48.files = images/48x48/qmmp.png
    icon_svg.files = images/scalable/qmmp.svgz \
        images/scalable/qmmp-simple.svgz
    icon16.path = $$DATA_DIR/icons/hicolor/16x16/apps
    icon32.path = $$DATA_DIR/icons/hicolor/32x32/apps
    icon48.path = $$DATA_DIR/icons/hicolor/48x48/apps
    icon_svg.path = $$DATA_DIR/icons/hicolor/scalable/apps
    INSTALLS += desktop \
        target \
        icon16 \
        icon32 \
        icon48 \
        icon_svg
}

win32 {
    LIBS += -lqmmp0 -lqmmpui0
    QMAKE_LIBDIR += ../../bin
    RC_FILE = qmmp.rc
}