src/plugins/Input/mpeg/mpeg.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

include(../../plugins.pri)

TARGET = $$PLUGINS_PREFIX/Input/mpeg

HEADERS += decodermpegfactory.h \
    settingsdialog.h \
    tagextractor.h \
    mpegmetadatamodel.h

SOURCES += decodermpegfactory.cpp \
    settingsdialog.cpp \
    tagextractor.cpp \
    mpegmetadatamodel.cpp

contains(CONFIG, WITH_MAD){
    HEADERS += decoder_mad.h
    SOURCES += decoder_mad.cpp
    DEFINES += WITH_MAD
}

contains(CONFIG, WITH_MPG123){
    HEADERS += decoder_mpg123.h
    SOURCES += decoder_mpg123.cpp
    DEFINES += WITH_MPG123
}

FORMS += settingsdialog.ui

RESOURCES = translations/translations.qrc

unix {
    target.path = $$PLUGIN_DIR/Input
    INSTALLS += target
    PKGCONFIG += taglib
    contains(CONFIG, WITH_MAD):PKGCONFIG += mad
    contains(CONFIG, WITH_MPG123):PKGCONFIG += libmpg123
}

win32 {
    LIBS += -ltag.dll
    contains(CONFIG, WITH_MAD):LIBS += -lmad
    contains(CONFIG, WITH_MPG123):LIBS += -lmpg123.dll
}